SED(1) | General Commands Manual | SED(1)

# NAME

`sed` — stream editor

# SYNOPSIS

`sed` | [`-aEnru`] [`-i`[extension]] command [file ...]

`sed` | [`-aEnru`] [`-e` command] [`-f` command_file] [`-i`[extension]] [file ...]

# DESCRIPTION

The `sed` utility reads the specified files, or the standard input if no files are specified, modifying the input as specified by a list of commands. The input is then written to the standard output.

A single command may be specified as the first argument to `sed`. Multiple commands may be specified separated by newlines or semicolons, or by using the `-e` or `-f` options. All commands are applied to the input in the order they are specified regardless of their origin.

The options are as follows:

`-a`
  The files listed as parameters for the `w` function or flag are created (or truncated) before any processing begins, by default. The `-a` option causes `sed` to delay opening each file until a command containing the related `w` function or flag is applied to a line of input.
`-E`
  Interpret regular expressions using POSIX extended regular expression syntax. The default behaviour is to use POSIX basic regular expression syntax.
`-e` command
  Append the editing commands specified by the command argument to the list of commands.
`-f` command_file
  Append the editing commands found in the file command_file to the list of commands. The editing commands should each be listed on a separate line.
`-i`[extension]
  Edit files in place, saving backups with the specified extension. If a zero length extension is given, no backup will be saved. It is not recommended to give a zero length extension when in place editing files, as it risks corruption or partial content in situations where disk space is exhausted, etc. In `-i` mode, the hold space, line numbers, and ranges are reset between files.
`-r`
  An alias for `-E`, for compatibility with GNU sed.
`-n`
  By default, each line of input is echoed to the standard output after all of the commands have been applied to it. The `-n` option suppresses this behavior.
`-u`
  Force output to be line buffered, printing each line as it becomes available. By default, output is line buffered when standard output is a terminal and block buffered otherwise. See setvbuf(3) for a more detailed explanation.

The form of a `sed` command is as follows:

`[address[,address]]function[arguments]`

Whitespace may be inserted before the first address and the function portions of the command.

Normally, `sed` cyclically copies a line of input, not including its terminating newline character, into a pattern space, (unless there is something left after a `D` function), applies all of the commands with addresses that select that pattern space, copies the pattern space to the standard output, appending a newline, and deletes the pattern space.

Some of the functions use a hold space to save all or part of the pattern space for subsequent retrieval.

# SED ADDRESSES

An address is not required, but if specified must be a number (that counts input lines cumulatively across input files), a dollar character (‘`$`’) that addresses the last line of input, or a context address, which is a regular expression preceded and followed by a delimiter. The delimiter can be any character except a newline or a backslash. Unless it is a slash, the opening delimiter needs to be escaped with a backslash.

A command line with no addresses selects every pattern space.

A command line with one address selects all of the pattern spaces that match the address.

A command line with two addresses selects the inclusive range from the first pattern space that matches the first address through the next pattern space that matches the second. If the second address is a number less than or equal to the line number first selected, only the first address is selected. Starting at the first line following the selected range, `sed` starts looking again for the first address.

Editing commands can be applied to non-selected pattern spaces by use of the exclamation character (‘`!`’) function.

# SED REGULAR EXPRESSIONS

By default, `sed` regular expressions are basic regular expressions (BREs). Extended regular expressions are supported using the `-E` and `-r` options. See re_format(7) for more information on regular expressions. In addition, `sed` has the following two additions to BREs:

1. The character delimiting the regular expression can be used inside the regular expression by prepending a backslash or by including it in a character class. For example, in the context address \x\x[xy]x, the RE delimiter is an ‘x’ and the other ‘x’ characters stand for themselves, so that the regular expression is “x[xy]”.

2. The escape sequence \n matches a newline character embedded in the pattern space. You can't, however, use a literal newline character in an address or in the substitute command.

One special feature of `sed` regular expressions is that they can default to the last regular expression used. If a regular expression is empty, i.e., just the delimiter characters are specified, the last regular expression encountered is used instead. The last regular expression is defined as the last regular expression used as part of an address or substitute command, and at run-time, not compile-time. For example, the command “/abc/s//XXX/” will substitute “XXX” for the pattern “abc”.

# SED FUNCTIONS

In the following list of commands, the maximum number of permissible addresses for each command is indicated by [0addr], [1addr], or [2addr], representing zero, one, or two addresses.

The argument text consists of one or more lines. To embed a newline in the text, precede it with a backslash. Other backslashes in text are deleted and the following character taken literally.

The `r` and `w` functions, as well as the `w` flag to the `s` function, take a file parameter, which should be separated from the function or flag by whitespace. Files are created (or their contents truncated) before any input processing begins.

The `b`, `r`, `s`, `t`, `w`, `y`, and `:` functions all accept additional arguments. The synopses below indicate which arguments have to be separated from the function letters by whitespace characters.

The `a`, `c`, `i`, `r`, and `w` functions cannot be followed by another command separated with a semicolon. The text and file arguments may contain semicolon characters.

Functions can be combined to form a function list, a list of `sed` functions each followed by a newline, as follows:

    { function
      function
      ...
      function
    }

The braces can be preceded and followed by whitespace. The functions can be preceded by whitespace as well.

Functions and function lists may be preceded by an exclamation mark, in which case they are applied only to lines that are not selected by the addresses.

[2addr]function-list
  Execute function-list only when the pattern space is selected.
[1addr]`a`\
text
  Write text to standard output immediately before each attempt to read a line of input, whether by executing the `N` function or by beginning a new cycle.
[2addr]`b` [label]
  Branch to the `:` function with the specified label. If the label is not specified, branch to the end of the script.
[2addr]`c`\
text
  Delete the pattern space and start the next cycle. With 0 or 1 address or at the end of a 2-address range, text is written to the standard output.
[2addr]`d`
  Delete the pattern space and start the next cycle.
[2addr]`D`
  Delete the initial segment of the pattern space through the first newline character and start the next cycle.
[2addr]`g`
  Replace the contents of the pattern space with the contents of the hold space.
[2addr]`G`
  Append a newline character followed by the contents of the hold space to the pattern space.
[2addr]`h`
  Replace the contents of the hold space with the contents of the pattern space.
[2addr]`H`
  Append a newline character followed by the contents of the pattern space to the hold space.
[1addr]`i`\
text
  Write text to the standard output.
[2addr]`l`
  (The letter ell.) Write the pattern space to the standard output in a visually unambiguous form. This form is as follows:

  backslash
    \\
  alert
    \a
  backspace
    \b
  form-feed
    \f
  carriage-return
    \r
  tab
    \t
  vertical tab
    \v

  Non-printable characters are written as three-digit octal numbers (with a preceding backslash) for each byte in the character (most significant byte first). Long lines are folded, with the point of folding indicated by displaying a backslash followed by a newline. The end of each line is marked with a ‘`$`’.

[2addr]`n`
  Write the pattern space to the standard output if the default output has not been suppressed, and replace the pattern space with the next line of input.
[2addr]`N`
  Append the next line of input to the pattern space, using an embedded newline character to separate the appended material from the original contents. Note that the current line number changes.
[2addr]`p`
  Write the pattern space to standard output.
[2addr]`P`
  Write the pattern space, up to the first newline character, to the standard output.
[1addr]`q`
  Branch to the end of the script and quit without starting a new cycle or file.
[1addr]`r` file
  Copy the contents of file to the standard output immediately before the next attempt to read a line of input. If file cannot be read for any reason, it is silently ignored and no error condition is set.
[2addr]`s`/RE/replacement/flags
  Substitute the replacement string for the first instance of the regular expression RE in the pattern space. Any character other than backslash or newline can be used instead of a slash to delimit the regular expression and the replacement. Also see the section about SED REGULAR EXPRESSIONS.

  An ampersand (‘`&`’) appearing in the replacement is replaced by the string matching the regular expression. The string ‘`\#`’, where ‘`#`’ is a digit, is replaced by the text matched by the corresponding backreference expression (see re_format(7)).

  All other instances of a backslash will print the literal character following it. Using a backslash before any other character other than ‘`&`’, ‘`\`’, digit, newline (ascii 0x0a), and the delimiter is unspecified and might not be portable to other implementations of `sed`.

  The value of flags in the substitute function is zero or more of the following:

  N
    Make the substitution only for the N'th occurrence of the regular expression in the pattern space, where N is a positive integer starting with `1` ... `9`.
  `g`
    Make the substitution for all non-overlapping matches of the regular expression, not just the first one.
  `p`
    Write the pattern space to standard output if a replacement was made. If the replacement string is identical to that which it replaces, it is still considered to have been a replacement.
  `w` file
    Append the pattern space to file if a replacement was made. If the replacement string is identical to that which it replaces, it is still considered to have been a replacement.
[2addr]`t` [label]
  Branch to the `:` function bearing the label if any substitutions have been made since the most recent reading of an input line or execution of a `t` function. If no label is specified, branch to the end of the script.
[2addr]`w` file
  Append the pattern space to the file.
[2addr]`x`
  Swap the contents of the pattern and hold spaces.
[2addr]`y`/string1/string2/
  Replace all occurrences of characters in string1 in the pattern space with the corresponding characters from string2. Any character other than a backslash or newline can be used instead of a slash to delimit the strings.

  Within string1 and string2, a backslash followed by another backslash is replaced by a single backslash, a backslash followed by an ‘n’ is replaced by a newline character, and a backslash followed by the delimiting character is replaced by that character, causing it to be treated literally, with the exception of the ‘n’ character, which will still be treated like a newline character. It is an error for a backslash to not be followed by another backslash, ‘n’, or the delimiting character, or for string1 to contain repeating characters.

[0addr]`:`label
  This function does nothing; it bears a label to which the `b` and `t` commands may branch.
[1addr]`=`
  Write the line number to the standard output followed by a newline character.
[0addr]
  Empty lines are ignored.
[0addr]`#`
  The ‘`#`’ and the remainder of the line are ignored (treated as a comment), with the single exception that if the first two characters in the file are ‘`#n`’, the default output is suppressed. This is the same as specifying the `-n` option on the command line.

# ENVIRONMENT

`COLUMNS`
  If set to a positive integer, output from the `l` function is formatted to the given width in columns. Otherwise, `sed` defaults to the terminal width, or 80 columns if the output is not a terminal.

# EXIT STATUS

The `sed` utility exits 0 on success, and >0 if an error occurs.

# SEE ALSO

awk(1), ed(1), grep(1), re_format(7)

Lee E. McMahon, SED — A Non-interactive Text Editor, AT&T Bell Laboratories, Computing Science Technical Report, 77, January 1979.

# STANDARDS

The `sed` utility is compliant with the IEEE Std 1003.1-2008 (“POSIX.1”) specification.

The flags [`-aEiru`] are extensions to that specification.

Following the `b`, `t`, or `:` commands with a semicolon and another command is an extension to the specification.

The use of newlines to separate multiple commands on the command line is non-portable; the use of newlines to separate multiple commands within a command file (`-f` command_file) is portable.

# HISTORY

A `sed` command first appeared outside of Bell Labs in PWB/UNIX 1.0. It was replaced in 4.4BSD.

# AUTHORS

Lee McMahon wrote the original implementation at the Bell Labs Computing Science Research Center. The 4.4BSD implementation was written by
Diomidis Spinellis.

December 10, 2024 | Debian